[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

12. Grafische Darstellung


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

12.1 Einführung in die grafische Darstellung

Maxima verwendet externe Grafikprogramme, um grafische Darstellungen auszugeben. Die Grafikfunktionen berechnen die Punkte der Grafik und senden diese mit einem Satz an Kommandos an das externe Grafikprogramm. Die Daten werden als Datenstrom über eine Pipe oder als eine Datei an das Grafikprogramm übergeben. Die Datei erhält den Namen maxout.interface, wobei interface der Name des externen Grafikprogramms ist. Die möglichen Dateiendungen sind: gnuplot, xmaxima, mgnuplot oder gnuplot_pipes.

Die Datei maxout.interface wird in dem Verzeichnis gespeichert, das durch die Systemvariable maxima_tempdir bezeichnet wird.

Die Datei maxout.interface kann wiederholt an das Grafikprogramm übergeben werden. Gibt Maxima keine Grafik aus, kann diese Datei geprüft werden, um mögliche Fehler festzustellen.

Das Paket draw ist eine Alternative, um Funktionsgraphen und eine Vielzahl anderer Graphen zu erstellen. Das Paket draw hat einen größeren Umfang an Funktionalitäten und ist flexibler, wenn der Graph besondere Formatierungen enthalten soll. Einige Grafikoptionen sind in beiden beiden Grafikpaketen vorhanden, können sich aber in der Syntax unterscheiden. Mit dem Kommando ? opt, wobei opt eine Grafikoption ist, wird möglicherweise nur die Dokumentation der Standard-Grafikroutinen angezeigt. Um auch die entsprechende Grafikoption des Paketes draw zu sehen, kann ?? opt auf der Kommandozeile eingegeben werden. Siehe draw.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

12.2 Grafikformate

Maxima verwendet für die Ausgabe von Grafiken die Grafikprogramme Gnuplot oder Xmaxima. Mit der Grafikoption plot_format können verschiedene Grafikformate für diese Programme ausgewählt werden. Die Grafikformate sind:


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

12.3 Funktionen und Variablen für die grafische Darstellung

Funktion: contour_plot (expr, x_range, y_range, options, …)

Zeichnet einen Konturgraphen (die Isolinien einer Funktion) von expr im Bereich x_range und y_range mit den Optionen options. expr ist ein Ausdruck oder der Name einer Funktion f(x,y) mit zwei Argumenten. Alle weiteren Argumente entsprechen denen der Funktion plot3d.

Die Funktion steht nur für die Grafikformate gnuplot und gnuplot_pipes zur Verfügung. Das Paket implicit_plot enthält die Funktion implicit_plot mit der für alle Grafikformate Konturgraphen erstellt werden können.

Beispiele:

(%i1) contour_plot(x^2 + y^2, [x, -4, 4], [y, -4, 4])$

../figures/contour1

(%i1) f(x, y) := x^3 + y^2;
                                   3    2
(%o1)                  f(x, y) := x  + y
(%i2) contour_plot(f, [u, -4, 4], [v, -4, 4])$

../figures/contour2

Es kann jede Option genutzt werden, die von der Funktion plot3d akzeptiert wird. Standardmäßig zeichnet Gnuplot den Graphen mit 3 Isolinien. Die Anzahl der Isolinien kann mit der Gnuplot-Option gnuplot_preamble erhöht werden. In diesem Beispiel werden 12 Isolinien gezeichnet und die Legende ist entfernt.

(%i1) contour_plot (u^3 + v^2, [u, -4, 4], [v, -4, 4], 
  [legend,false], [gnuplot_preamble, "set cntrparam levels 12"])$

../figures/contour3

Funktion: get_plot_option (keyword, index)

Gibt die Werte der Parameter der Option mit dem Namen keyword zurück. Die Optionen und ihre Parameter sind in der Variablen plot_options gespeichert. Hat index den Wert 1 wird der Name der Option keyword zurückgeben. Der Wert 2 für index gibt den Wert des ersten Parameters zurück, und so weiter.

Siehe auch plot_options, set_plot_option und das Kapitel Grafikoptionen.

Beispiel:

(%i1) get_plot_option(color,1);
(%o1)                         color
(%i2) get_plot_option(color,2);
(%o2)                         blue
(%i3) get_plot_option(color,3);
(%o3)                          red

Funktion: implicit_plot (expr, x_range, y_range)
Funktion: implicit_plot ([expr_1, …, expr_n], x_range, y_range)

Zeichnet den Graphen eines oder mehrerer Ausdrücke, die implizit gegeben sind. expr ist der Ausdruck der gezeichnet werden soll, x_range ist der Wertebereich der x-Achse und y_range der Wertebereich der y-Achse. Die Funktion implicit_plot beachtet die Werte der Parameter der Grafikoptionen, die in der Systemvariablen plot_options enthalten sind. Grafikoptionen können auch als Argumente übergeben werden.

Der Algorithmus von implicit_plot stellt Vorzeichenwechsel der Funktion in den Bereichen x_range und y_range fest. Für komplizierte Flächen kann der Algorithmus versagen.

Die Funktion wird mit dem Kommando load(implicit_plot) geladen.

Beispiel:

(%i1) implicit_plot (x^2 = y^3 - 3*y + 1, [x, -4, 4], [y, -4, 4],
 [gnuplot_preamble, "set zeroaxis"]);

../figures/implicit_plot

Funktion: make_transform ([var1, var2, var3], fx, fy, fz)

Gibt eine Funktion zurück, die als Parameter für die Grafikoption transform_xy geeignet ist. Die zwei Argumente var1 und var2 repräsentieren die zwei unabhängigen Variablen der Funktion plot3d. Das dritte Argument var3 ist die Funktion, die von den zwei Variablen abhängt. Die drei Funktionen fx, fy und fz müssen von den drei Argumenten var1, var2 und var3 abhängen und die Argumente der Funktion plot3d in kartesische Koordinaten für die Ausgabe des Graphen transformieren.

Die Transformationen polar_to_xy für die Transformation von Polarkoordinaten und spherical_to_xyz für die Transformation von Kugelkoordinaten in kartesische Koordinaten sind bereits definiert.

Beispiel:

Definition der Transformation von Zylinderkoordinaten nach kartesischen Koordinaten. Die Definition ist identisch mit der für polar_to_xy.

Der Graph zeigt einen Kegel.

(%i1) cylinder_to_xy:make_transform([r,phi,z],r*cos(phi),
                                              r*sin(phi),z)$
(%i2) plot3d(-r,[r,0,3],[phi,0,2*%pi],
                        [transform_xy, cylinder_to_xy])$

Systemfunktion: polar_to_xy

Kann als Parameter der Grafikoption transform_xy der Funktion plot3d übergeben werden. Der Parameter polar_to_xy bewirkt, dass die zwei unabhängigen Variablen der Funktion plot3d von Polarkoordinaten in kartesische Koordinaten transformiert werden.

Für ein Beispiele siehe make_transform.

Funktion: plot2d (plot, x_range, …, options, …)
Funktion: plot2d ([plot_1, …, plot_n], …, options, …)
Funktion: plot2d ([plot_1, …, plot_n], x_range, …, options, …)

plot, plot_1, …, plot_n sind Ausdrücke, Namen von Funktionen oder Listen, mit denen diskrete Punkte oder Funktionen in einer parametrischen Darstellung angegeben werden. Diskrete Punkte können als [discrete, [x1, ..., xn], [y1, ..., yn]] oder als [discrete, [[x1, y1], ..., [xn, ..., yn]] angegeben werden. Eine parametrische Darstellung hat die Form [parametric, x_expr, y_expr, t_range].

Die Funktion plot2d zeichnet einen zweidimensionalen Graphen einer oder mehrerer Ausdrücke als Funktion einer Variablen oder eines Parameters. Mit der Grafikoption x_range wird der Name der unabhängigen Variablen und deren Bereich angegeben. Die Syntax der Grafikoption x_range ist: [variable, min, max].

Ein diskreter Graph wird durch eine Liste definiert, die mit dem Schlüsselwort disrecte beginnt. Es folgen ein oder zwei Listen mit den Werten. Werden zwei Listen übergeben, müssen diese dieselbe Länge haben. Die Daten der ersten Listen werden als die x-Koordinaten der Punkte und die der zweiten als die y-Koordinaten der Punkte interpretiert. Wird nur eine Liste übergeben, sind die Elemente Listen mit je zwei Elementen, die die x- und y-Koordinaten der Punkte repräsentieren.

Ein parametrischer Graph wird durch eine Liste definiert, die mit dem Schlüsselwort parametric beginnt. Es folgen zwei Ausdrücke oder Namen von Funktionen und ein Parameter. Der Bereich für den Parameter muss eine Liste sein, die den Namen des Parameters, seinen größten und seinen kleinsten Wert enthält: [parameter, min, max]. Der Graph ist der Weg für die zwei Ausdrücke oder Namen von Funktionen, wenn der Parameter parameter von min nach max zunimmt.

Als optionales Argument kann ein Wertebereich für die vertikale Koordinatenachse mit der Grafikoption y angegeben werden: [y, min, max]. Die vertikale Achse wird immer mit dem Schlüsselwort y bezeichnet. Wird kein Wertebereich y angegeben, wird dieser durch den größten und kleinsten y-Wert des zu zeichnenden Graphen festgelegt.

Auch alle anderen Grafikoptionen werden als Listen angegeben, die mit einem Schlüsselwort beginnen, auf das die Parameter der Grafikoption folgen. Siehe plot_options.

Werden mehrere Graphen gezeichnet, wird eine Legende hinzugefügt, die die einzelnen Graphen unterscheidet. Mit der Grafikoption legend können die Bezeichnungen für die Legende festgelegt werden. Wird diese Option nicht genutzt, generiert Maxima die Bezeichnungen der Legende aus den Ausdrücken oder Namen der Funktionen, die als Argument übergeben wurden.

Siehe auch das Kapitel Grafikoptionen.

Beispiele:

Graph einer einfachen Funktion.

(%i1) plot2d (sin(x), [x, -%pi, %pi])$

../figures/plotting2

Wächst die Funktion sehr schnell, kann es notwendig sein, die Werte auf der vertikalen Achse mit der Grafikoption y zu begrenzen.

(%i1) plot2d (sec(x), [x, -2, 2], [y, -20, 20])$
plot2d: some values were clipped.

../figures/plotting3

Die Ansicht eines Graphen kann sich für verschiedene Grafikprogramme unterscheiden. In Xmaxima bewirkt die Grafikoption [box, false], das die Koordinatenachsen mit Pfeilen dargestellt werden.

(%i1) plot2d ( x^2-1, [x, -3, 3], [y, -2, 10], 
                      [box, false], 
                      [plot_format, xmaxima])$

../figures/plotting1

Ein Graph mit einer logarithmischen Skala:

(%i1) plot2d (exp(3*s), [s, -2, 2], [logy])$

../figures/plotting4

Graphen von Funktionen, deren Namen als Argumente übergeben werden.

(%i1) F(x) := x^2 $
(%i2) :lisp (defun |$g| (x) (m* x x x))
$g
(%i2) H(x) := if x < 0 then x^4 - 1 else 1 - x^5 $
(%i3) plot2d ([F, G, H], [u, -1, 1], [y, -1.5, 1.5])$

../figures/plotting5

Graph einer parametrisch definierten Schmetterlingskurve.

(%i1) r: (exp(cos(t))-2*cos(4*t)-sin(t/12)^5)$
(%i2) plot2d([parametric, r*sin(t), r*cos(t), [t, -8*%pi, 8*%pi], 
             [nticks, 2000]])$

../figures/plotting6

Ein parametrischer Kreis mit zwei vollständigen Drehungen, der nur für 7 Punkte gezeichnet ist.

(%i1) plot2d ([parametric, cos(t), sin(t), [t, -2*%pi, 2*%pi], 
              [nticks, 8]])$

../figures/plotting7

Graph der Funktion abs(x) und eines parametrischen Kreises. Das Seitenverhältnis der Grafik wurde mit den Grafikoptionen x und y so angepasst, dass der Kreis rund erscheint. Das hier gewählte Seitenverhältnis funktioniert gut für die Ausgabe im Postscript-Format.

(%i1) plot2d([[parametric, cos(t), sin(t) ,[t,0,2*%pi], 
        [nticks, 80]], abs(x)], [x,-2,2], [y, -1.5, 1.5])$
plot2d: some values were clipped.

../figures/plotting8

Graph für diskrete Punkte. Die Punkte sind in zwei separaten Listen jeweils für die x- und y-Koordinaten angegeben. Standardmäßig werden die Punkte mit einer Linie verbunden.

(%i1) plot2d([discrete, [10, 20, 30, 40, 50], 
                        [.6, .9, 1.1, 1.3, 1.4]])$

../figures/plotting9

Dieselben Punkte des letzten Beispiels. Jeder Punkt wird einzeln in eine Liste eingetragen und die Punkte werden nicht miteinander verbunden.

(%i1) plot2d([discrete, [[10, .6], [20, .9], [30, 1.1], 
                         [40, 1.3], [50, 1.4]]],
                         [style, points])$

../figures/plotting10

In diesem Beispiel wird eine Tabelle mit drei Spalten in eine Datei data.txt gespeichert. Die Datei wird gelesen und die zweite und dritte Spalte werden gezeichnet.

(%i1) with_stdout ("data.txt", 
                   for x:0 thru 10 do print (x, x^2, x^3))$
(%i2) data: read_matrix ("data.txt")$
(%i3) plot2d ([discrete, transpose(data)[2], transpose(data)[3]],
  [style,points], [point_type,diamond], [color,red])$

../figures/plotting11

Graph von experimentellen Datenpunkten zusammen mit einer theoretischen Funktion, die die Daten beschreibt.

(%i1) xy: [[10, .6], [20, .9], [30, 1.1], [40, 1.3], [50, 1.4]]$
(%i2) plot2d([[discrete, xy], 2*%pi*sqrt(l/980)], [l,0,50],
        [style, points, lines], [color, red, blue], 
        [point_type, asterisk], [legend, "experiment", "theory"],
        [xlabel, "pendulum's length (cm)"], 
        [ylabel, "period (s)"])$

../figures/plotting12

Funktion: plot3d (expr, x_range, y_range, …, options, …)
Funktion: plot3d ([expr_1, …, expr_n], x_range, y_range, …, options, …)

Zeichnet einen Graph mit einer oder mehreren Flächen, die als eine Funktion von zwei Variablen oder in parametrischer Form definiert sind.

Die zu zeichnenden Funktionen werden als Ausdrücke oder mit ihrem Namen als Argumente übergeben. Mit der Maus kann der Graph rotiert werden, um die Fläche aus verschiedenen Blickwinkeln zu betrachten.

Siehe auch das Kapitel Grafikoptionen.

Beispiele:

Graph einer einfachen Funktion.

(%i1) plot3d (2^(-u^2 + v^2), [u, -3, 3], [v, -2, 2])$

../figures/plotting13

Mit der Grafikoption z wird der Wertebereich der z-Achse begrenzt. Dieses Beispiel zeigt den Graph ohne Färbung der Fläche.

(%i1) plot3d ( log ( x^2*y^2 ), [x, -2, 2], [y, -2, 2], [z, -8, 4],
               [palette, false], [color, magenta, blue])$

../figures/plotting14

Unendlich große Werte der z-Koordinate können auch durch Wahl eines Gitters vermieden werden, das nicht mit einer der Asymptoten zusammenfällt. Das Beispiel zeigt zudem die Nutzung einer vordefinierten Palette.

(%i1) plot3d (log (x^2*y^2), [x, -2, 2], [y, -2, 2], 
         [grid, 29, 29], [palette, get_plot_option(palette,5)])$

../figures/plotting15

Graph mit zwei Flächen, die denselben Wertebereich haben und eine Palette nutzen.

(%i1) plot3d ([2^(-x^2 + y^2), 4*sin(3*(x^2+y^2))/(x^2+y^2), 
              [x, -3, 3], [y, -2, 2]])$

../figures/plotting16

Die gleichen zwei Flächen mit verschiedenen Wertebereichen. In Xmaxima nutzen die zwei Flächen verschiedene Paletten.

(%i1) plot3d ([[2^(-x^2 + y^2), [x,-2,2], [y,-2,2]], 
         4*sin(3*(x^2+y^2))/(x^2+y^2), [x, -3, 3], [y, -2, 2]],
         [plot_format,xmaxima])$

../figures/plotting17

Graph der kleinschen Flasche, die parametrisch definiert ist.

(%i1) expr_1: 5*cos(x)*(cos(x/2)*cos(y) 
              + sin(x/2)*sin(2*y) + 3.0) - 10.0$
(%i2) expr_2: -5*sin(x)*(cos(x/2)*cos(y) 
              + sin(x/2)*sin(2*y) + 3.0)$
(%i3) expr_3: 5*(-sin(x/2)*cos(y) + cos(x/2)*sin(2*y))$
(%i4) plot3d ([expr_1, expr_2, expr_3], [x, -%pi, %pi],
        [y, -%pi, %pi], [grid, 40, 40])$

../figures/plotting18

Graph einer Kugelfunktion, die vordefinierte Koordinatentransformation spherical_to_xyz wird verwendet, um von Kugelkoordinaten in ein kartesisches Koordinatensystem zu transformieren.

(%i1) plot3d (sin(2*theta)*cos(phi), 
        [theta, 0, %pi], [phi, 0, 2*%pi],
        [transform_xy, spherical_to_xyz], [grid,30,60])$

../figures/plotting19

Gebrauch der vordefinierten Funktion polar_to_xy, um von zylindrischen Koordinaten in ein kartesisches Koordinatensystem zu transformieren. Siehe auch polar_to_xy. Dieses Beispiel zeigt auch wie der Rahmen und die Legende entfernt werden können.

(%i1) plot3d (r^.33*cos(th/3), [r, 0, 1], [th, 0, 6*%pi], 
        [grid, 12, 80],
        [transform_xy, polar_to_xy], [box, false], [legend,false])$

../figures/plotting20

Graph einer Kugel, wobei die Koordinatentransformation von Kugelkoordinaten in ein kartesisches Koordinatensystem genutzt wird. In Xmaxima werden die drei Achsen gleichmäßig skaliert, um die Proportionen der Kugel zu bewahren. Eine Palette mit verschiedenen Schattierungen einer Farbe wird genutzt.

(%i1) plot3d( 5, [theta, 0, %pi], [phi, 0, 2*%pi], 
         [plot_format,xmaxima], [transform_xy, spherical_to_xyz], 
         [palette,[value,0.65,0.7,0.1,0.9]])$

../figures/plotting21

Definition einer Funktion mit zwei Variablen als eine Matrix. Der Quote-Operator ' in der Definition der Funktion verhindert, das plot3d fehlschlägt, wenn die Argumente keine ganze Zahlen sind.

(%i1) M: matrix([1, 2, 3, 4], [1, 2, 3, 2], [1, 2, 3, 4],
                [1, 2, 3, 3])$
(%i2) f(x, y) := float('M [round(x), round(y)])$
(%i3) plot3d (f(x,y), [x, 1, 4], [y, 1, 4], [grid, 4, 4])$
apply: subscript must be an integer; found: round(x)

../figures/plotting22

Wird die Höhenangabe elevation auf Null gesetzt, kann die Fläche als eine Karte betrachtet werden. Jede Farbe repräsentiert einen anderen Wert der Fläche. Die Option colorbox wird genutzt, um die Werte der Farben zu zeigen. Die Gitterlinien sind ausgeschaltet.

(%i1) plot3d (cos (-x^2 + y^3/4), [x, -4, 4], [y, -4, 4],
        [mesh_lines_color, false], [elevation, 0], [azimuth, 0],
        [colorbox, true], [grid, 150, 150])$

../figures/plotting23

Systemvariable: plot_options

Die Elemente dieser Liste definieren die Standardwerte für die Ausgabe von Graphen. Ist einer der Werte ein Argument der Funktionen plot2d oder plot3d, wird der Standardwert überschrieben. Die Standardwerte können mit der Funktion set_plot_option gesetzt werden. Einige Grafikoptionen sind nicht in der Liste plot_options enthalten.

Jedes Element der Liste plot_options ist eine Liste mit zwei oder mehr Einträgen. Der erste Eintrag ist der Name der Grafikoption. Die weiteren Einträge sind die Parameter der Option. In einigen Fällen kann der Parameter einer Option wiederum eine Liste sein.

Siehe auch set_plot_option, get_plot_option und das Kapitel Grafikoptionen.

Funktion: set_plot_option (option)

Akzeptiert die meisten der Optionen, die im Kapitel Grafikoptionen aufgelistet sind und speichert diese in der globalen Variable plot_options. set_plot_options wertet die Argumente aus und gibt die vollständige Liste plot_optons zurück.

Siehe auch plot_options, get_plot_option und das Kapitel Grafikoptionen.

Beispiele:

Setze einen neue Werte für die Grafikoption grid.

(%i1) set_plot_option ([grid, 30, 40]);
(%o1) [[t, - 3, 3], [grid, 30, 40], [transform_xy, false], 
[run_viewer, true], [axes, true], [plot_format, gnuplot_pipes], 
[color, blue, red, green, magenta, black, cyan], 
[point_type, bullet, circle, plus, times, asterisk, box, square, 
triangle, delta, wedge, nabla, diamond, lozenge], 
[palette, [hue, 0.25, 0.7, 0.8, 0.5], 
[hue, 0.65, 0.8, 0.9, 0.55], [hue, 0.55, 0.8, 0.9, 0.4], 
[hue, 0.95, 0.7, 0.8, 0.5]], [gnuplot_term, default], 
[gnuplot_out_file, false], [nticks, 29], [adapt_depth, 5], 
[gnuplot_preamble, ], [gnuplot_default_term_command, 
set term pop], [gnuplot_dumb_term_command, set term dumb 79 22], 
[gnuplot_ps_term_command, set size 1.5, 1.5;set term postscript \
eps enhanced color solid 24], [plot_realpart, false]]

Systemfunktion: spherical_to_xyz

Kann als Parameter für die Option transform_xy der Funktion plot3d übergeben werden. Der Parameter spherical_to_xyz bewirkt, dass die zwei unabhängigen Variablen und die Funktion beim Aufruf von plot3d von Kugelkoordinaten in kartesische Koordinaten umgerechnet werden.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

12.4 Grafikoptionen

Die Grafikoptionen bestehen aus einer Liste, die mit einem Schlüsselwort beginnt und ein oder mehrere Parameter enthält. Die meisten Optionen können mit den Funktionen plot2d, plot3d, contour_plot oder implicit_plot genutzt und mit der Funktion set_plot_option gesetzt werden. Auf Ausnahmen wird im Folgenden hingewiesen.

Grafikoption: adapt_depth [adapt_depth, integer]

Standardwert: 5

Die maximale Zahl an Teilungen von Intervallen, die der adaptive Algorithmus für das Zeichnen eines Graphen vornimmt. Zusammen mit der Grafikoption nticks hat diese Grafikoption Einfluss darauf, wie glatt der Graph gezeichnet wird.

Grafikoption: axes [axes, symbol]

Standardwert: true

symbol kann einen der Werte true, false, x oder y annehmen. Ist der Wert false, werden keine Achsen gezeichnet. Mit x oder y werden nur die x- oder nur die y-Achse gezeichnet. Mit true werden beide Achsen gezeichnet. Diese Option wird nur von den Funktionen plot2d und implicit_plot beachtet.

Grafikoption: azimuth [azimuth, number]

Standardwert: 30

Setzt den Wert des Azimutwinkels in Grad für die Ansicht einer dreidimensionalen Grafik. Siehe auch elevation.

Grafikoption: box [box, symbol]

Standardwert: true

Hat die Grafikoption box den Wert true, erhält die Grafik einen Rahmen. Ist der Wert false, wird kein Rahmen gezeichnet.

Grafikoption: color [color, color_1, …, color_n]

Standardwert: [blue, red, green, magenta, black, cyan]

Wenn die Funktionen plot2d oder implicit_plot mehrere Graphen zeichnen, definiert die Grafikoption color die Farben der einzelnen Graphen. Für einen 3D-Graphen mit der Funktion plot3d definiert die Grafikoption color die Farbe der Flächen.

Gibt es mehr Kurven oder Flächen als Farben, werden die Farben wiederholt. Im Grafikformat Gnuplot können nur die Farben blue, red, green, magenta, black, cyan verwendet werden. Im Grafikformat Xmaxima können die Farben auch als eine Zeichenkette angegeben werden, die mit dem Zeichen # beginnt und auf dem sechs hexadezimale Zahlenwerte folgen. Je zwei Werte bezeichnen die rote, grüne und blaue Komponente der Farbe.

Siehe auch style.

Grafikoption: colorbox [colorbox, symbol]

Standardwert: false

Hat die Grafikoption colorbox den Wert true, wird immer dann, wenn das Grafikkommando plot3d eine Palette mit verschiedenen Farben nutzt, um die z-Werte darzustellen, eine Legende mit den Farben und den dazugehörenden z-Werten angezeigt.

Grafikoption: elevation [elevation, number]

Standardwert: 60

Setzt den Wert des Elevationswinkels in Grad für die Ansicht einer dreidimensionalen Grafik. Siehe auch azimuth.

Grafikoption: grid [grid, integer, integer]

Standardwert: [30, 30]

Setzt die Anzahl der Gitterlinen für die x- und y-Achsen einer dreidimensionalen Grafik.

Grafikoption: legend [legend, string_1, …, string_n]
Grafikoption: legend [legend, false]

Definiert die Einträge einer Legende, wenn mehrere Graphen gezeichnet werden. Sind mehr Graphen als Einträge vorhanden, werden die Einträge wiederholt. Hat die Grafikoption legend den Wert false, wird keine Legende gezeichnet. Standardmäßig werden die Ausdrücke oder Namen der Funktionen als Einträge verwendet. Für diskrete Grafiken werden die Einträge mit discrete1, discrete2, … bezeichnet. Diese Grafikoption kann nicht mit der Funktion set_plot_option gesetzt werden.

Grafikoption: logx [logx]

Bewirkt, dass die horizontale Achse logarithmisch skaliert wird. Diese Grafikoption kann nicht mit der Funktion set_plot_option gesetzt werden. Siehe auch logy.

Grafikoption: logy [logy]

Bewirkt, dass die vertikale Achse logarithmisch skaliert wird. Diese Grafikoption kann nicht mit der Funktion set_plot_option gesetzt werden. Siehe auch logx.

Grafikoption: mesh_lines_color [mesh_lines_color, color]

Standardwert: black

Setzt die Farbe, die von der Funktion plot3d genutzt wird, um die Gitterlinien zu zeichnen. Es können dieselben Farben verwendet werden wie für die Grafikoption color. Hat mesh_lines_color Wert false, werden keine Gitterlinien gezeichnet.

Grafikoption: nticks [nticks, integer]

Standardwert: 29

Wird eine Grafik mit der Funktion plot2d gezeichnet, gibt nticks die Anzahl der Anfangspunkte für das Zeichnen der Grafik an. Werden parametrische Kurven mit den Funktionen plot2d oder plot3d gezeichnet, ist nticks die Anzahl der Punkte, für die der Graph gezeichnet wird.

Zusammen mit der Grafikoption adapt_depth hat diese Grafikoption Einfluss darauf, wie glatt der Graph gezeichnet wird.

Grafikoption: palette [palette, [palette_1], …, [palette_n]]
Grafikoption: palette [palette, false]

Standardwert: [hue, 0.25, 0.7, 0.8, 0.5], [hue, 0.65, 0.8, 0.9, 0.55], [hue, 0.55, 0.8, 0.9, 0.4], [hue, 0.95, 0.7, 0.8, 0.5]

Eine Palette kann aus einer oder einer Liste mit mehreren Paletten bestehen. Jede Palette beginnt mit einem Schlüsselwort, worauf 4 Zahlen folgen. Die ersten drei Zahlen haben Werte zwischen 0 und 1. Diese definieren den Farbton hue, die Sättigung saturation und die Grundfarbe value, die der kleinste z-Wert erhält. Die Schlüsselworte hue, saturation und value spezifizieren, welches der drei Attribute mit dem Wert von z geändert werden. Der letzte Wert der Liste, spezifiziert, welcher Wert zum größten z-Wert gehört. Dieser größte Wert kann größer als 1 und auch negativ sein. Die Werte der modifizierten Attribute werden Modulo 1 gerundet.

Gnuplot verwendet nur die erste Palette in einer Liste mit Paletten. Xmaxima nutzt alle Paletten nacheinander, wenn mehrere Flächen gezeichnet werden. Sind nicht genügend Paletten vorhanden, werden die Paletten wiederholt.

Die Farbe der Gitterlinien wird mit der Option mesh_lines_color   angegeben. Hat palette den Wert false, werden die Flächen nicht gefärbt, sondern als ein Gitternetz gezeichnet. Die Farbe der Gitterlinien wird in diesem Fall mit der Grafikoption color festgelegt.

Grafikoption: plot_format [plot_format, format]

Standardwert: gnuplot für Windows, ansonsten gnuplot_pipes

Setzt das Grafikformat für die Ausgabe einer Grafik. format kann die Werte gnuplot, xmaxima, mgnuplot oder gnuplot_pipes annehmen. Siehe das Kapitel Grafikformate.

Grafikoption: plot_realpart [plot_realpart, symbol]

Standardwert: false

Hat plot_realpart den Wert true, werden Funktionen als komplex angenommen und der Realteil wird gezeichnet. Das entspricht dem Aufruf der Grafikfunktion mit dem Ausdruck realpart(function). Hat plot_realpart den Wert false, wird keine Grafik gezeichnet, wenn die Funktion keinen Realteil hat. Zum Beispiel ist log(x) komplex, wenn x negativ ist. Hat plot_realpart den Wert true, wird der Wert log(-5) als log(5) gezeichnet. Hat plot_realpart den Wert false wird kein Wert gezeichnet.

Grafikoption: point_type [point_type, type_1, …, type_n]

Standardwert: [bullet, circle, plus, times, asterisk, box, square, triangle, delta, wedge, nabla, diamond, lozenge]

Werden im Grafikformat Gnuplot Punkte mit den Stilen points oder linespoints gezeichnet, werden die Symbole für die einzelnen Datensätze nacheinander der Liste point_type entnommen. Gibt es mehr Datensätze als Symbole, werden diese wiederholt. Siehe auch style.

Grafikoption: psfile [psfile, filename]

Speichert die Grafik in eine Postscript-Datei mit den Namen filename. Die Grafik wird nicht auf dem Bildschirm ausgegeben. Standardmäßig wird die Datei in dem Ordner abgespeichert, dessen Namen in der Optionsvariablen maxima_tempdir enthalten ist.

Grafikoption: run_viewer [run_viewer, symbol]

Standardwert: true

Kontrolliert, ob die Bildschirmausgabe des Grafikformats gestartet wird.

Grafikoption: style [style, type_1, …, type1_n]
Grafikoption: style [style, [style_1], …, [style_n]]

Standardwert: lines

Bestimmt den Stil für das Zeichnen von Funktionen oder Datensätzen mit der Funktion plot2d. Werden mehr Graphen gezeichnet, als Stile vorhanden sind, werden diese wiederholt. Die möglichen Stile sind lines für Linien, points für einzelne Punkte, linespoints für Linien mit Punkten oder dots für kleine Punkte. Das Grafikformat Gnuplot akzeptiert zusätzlich den Stil impulses.

Jeder Stil kann weitere Parameter erhalten, die zusammen mit dem Stil als eine Liste angegeben werden. Der Stil lines akzeptiert zwei Zahlen, die die Breite der Linie und deren Farbe angegeben. Die Standardfarben haben die Zahlenwerte: 1: blue, 2: red, 3: magenta, 4: orange, 5: brown, 6: lime und 7: aqua. Im Grafikformat Gnuplot kann die Kodierung der Farben für verschiedene Terminals abweichend sein. Wird zum Beispiel das Terminal [gnuplot_term,ps] verwendet, entspricht dem Zahlenwert 4 die Farbe black.

Der Stil points akzeptiert zwei oder drei Parameter. Der erste Parameter ist der Radius des Punktes. Der zweite Parameter ist eine Zahl, der wie für den Stil lines eine Farbe angibt. Der dritte Parameter ist eine Zahl, mit der im Grafikformat Gnuplot die folgenden Zeichen für die Darstellung der Punkte ausgewählt werden können: 1: bullet, 2: circle, 3: plus, 4: times, 5: asterisk, 6: box, 7: square, 8: triangle, 9: delta, 10: wedge, 11: nabla, 12: diamond, 13: lozenge.

Der Stil linesdots akzeptiert bis zu vier Parameter: die Breite der Linie, den Radius der Punkte, die Farbe und das Symbol für das Zeichnen der Punkte.

Siehe auch die Grafikoptionen color und point_type.

Grafikoption: t [t, min, max]

Bestimmt den Wertebereich für das Zeichnen einer parametrischen Kurve mit der Funktion plot2d. Die Variable einer parametrischen Kurve muss mit t bezeichnet werden.

Grafikoption: transform_xy [transform_xy, symbol]

Standardwert: false

symbol hat entweder den Wert false oder ist das Ergebnis der Funktion make_transform. Wenn verschieden von false, wird die Funktion genutzt, um die drei Koordinaten einer dreidimensionalen Grafik zu transformieren.

Siehe auch polar_to_xy und spherical_to_xyz. für bereits vordefinierte Koordinatentransformationen.

Grafikoption: x [x, min, max]

Die erste Grafikoption der Funktionen plot2d oder plot3d bezeichnet die unabhängige Variable. Die unabhängige Variable muss nicht mit x bezeichnet werden, sondern kann ein beliebiges von x verschiedenes Symbol sein. Die Werte min und max geben in diesem Fall den Wertebereich der unabhängigen Variablen an. Die Grafikoption x kann ein zweites Mal angegeben werden, um den Bereich für die x-Achse festzulegen.

Grafikoption: xlabel [xlabel, string]

Standardwert: "x"

Legt die Zeichenkette string fest, mit der die x-Achse der Grafik bezeichnet wird. Der Standardwert ist "x" oder der Name der ersten unabhängigen Variablen. Diese Grafikoption kann nicht mit dem Kommando set_plot_option gesetzt werden.

Grafikoption: y [y, min, max]

Für einen dreidimensionalen Graphen legt diese Grafikoption die zweite unabhängige Variable fest. Die unabhängige Variable muss nicht mit y bezeichnet werden, sondern kann ein beliebiges von y verschiedenes Symbol sein. Die Werte min und max geben in diesem Fall den Wertebereich der Variablen an. Wird die Grafikoption für einen zweidimensionalen Graphen verwendet oder für einen dreidimensionalen Graphen ein zweites Mal eingesetzt, dann wird der Bereich für die y-Achse festgelegt.

Grafikoption: ylabel [ylabel, string]

Standardwert: "y"

Legt die Zeichenkette string fest, mit der die y-Achse der Grafik bezeichnet wird. Der Standardwert ist "y" oder für den Fall einer dreidimensionalen Grafik der Name der zweiten unabhängigen Variablen. Diese Grafikoption kann nicht mit dem Kommando set_plot_option gesetzt werden.

Grafikoption: z [z, min, max]

Legt für eine dreidimensionalen Grafik den Bereich für die z-Achse fest.

Grafikoption: zlabel [zlabel, string]

Standardwert: "z"

Legt die Zeichenkette string fest, mit der die z-Achse der Grafik bezeichnet wird. Der Standardwert ist "z". Diese Grafikoption kann nicht mit dem Kommando set_plot_option gesetzt werden und wird von den Funktionen plot2d sowie implicit_plot ignoriert.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

12.5 Gnuplot Optionen

Es gibt einige spezielle Optionen für das Grafikformat Gnuplot. Diese Optionen werden mit einem Schlüsselwort bezeichnet und zusammen mit einer Zeichenkette, die ein gültiges Gnuplot-Kommando darstellt, an Gnuplot übergeben. In den meisten Fällen gibt es eine entsprechende Grafikoption, die ein vergleichbares Ergebnis erzeugt. Die Grafikoptionen sollten den Gnuplot-Optionen vorgezogen werden.

Grafikoption: gnuplot_term

Setzt den Terminaltyp für das Grafikformat Gnuplot.

Gnuplot kann Ausgaben in verschiedenen Formaten wie zum Beispiel PNG, JPEG, SVG generieren. Die verschiedenen Formate werden mit der Option gnuplot_term angegeben. Weiterhin kann jedes gültige Kommando als Zeichenkette übergeben werden. Zum Beispiel generiert [gnuplot_term, png] eine Grafik im PNG-Format. Das Kommando [gnuplot_term, "png size 1000, 1000"] generiert eine Grafik im PNG-Format mit dem Format 1000 x 1000 Punkte. Erhält die Grafikoption gnuplot_out_file den Wert filename, wird die Ausgabe in die Datei filename geschrieben. Ansonsten werden die Kommandos in die Datei maxplot.term geschrieben, wobei term das verwendete Grafikformat ist.

Grafikoption: gnuplot_out_file

Zusammen mit der Option gnuplot_term, kann die Ausgabe in dem angegebenen Gnuplot-Format in eine Datei geschrieben werden. Eine Postscript-Datei kann auch mit der Grafikoption psfile angegeben werden. Die Grafikoption psfile funktioniert auch mit dem Grafikformat xmaxima.

[gnuplot_term, png], [gnuplot_out_file, "graph3.png"]

Grafikoption: gnuplot_pm3d

Hat die Grafikoption gnuplot_pm3d den Wert false, wird der PM3D-Modus ausgeschaltet. Dieser Modus ist standardmäßig eingeschaltet.

Grafikoption: gnuplot_preamble

Fügt Gnuplot-Kommandos ein, die vor dem Zeichnen der Grafik ausgeführt werden. Jedes gültige Gnuplot-Kommando kann verwendet werden. Mehrere Kommandos sollten mit einem Semikolon voneinander getrennt werden. Der Standardwert der Option gnuplot_preamble ist eine leere Zeichenkette "".

Grafikoption: gnuplot_curve_titles

Dies ist eine veraltete Option, die von der Grafikoption legend ersetzt wurde.

Grafikoption: gnuplot_curve_styles

Dies ist eine veraltete Option, die von der Grafikoption style ersetzt wurde.

Grafikoption: gnuplot_default_term_command

Das Gnuplot-Kommando, um den Standardtyp eines Terminals zu setzen. Der Standardwert ist set term pop.

Grafikoption: gnuplot_dumb_term_command

Das Gnuplot-Kommando, um die Breite und Höhe des Terminaltyps dumb zu setzen. Der Standardwert ist "set term dumb 79 22". Die Ausgabe hat eine Breite von 79 Zeichen und eine Höhe von 22 Zeichen.

Grafikoption: gnuplot_ps_term_command

Das Gnuplot-Kommando, um die Parameter für eine Postscript-Terminal zu setzen. Ein Postscript-Terminal hat die Standardwerte "set size 1.5, 1.5; set term postscript eps enhanced color solid 24". Das Terminal wird auf den 1,5 fachen Wert des Standardwertes und die Schriftgröße auf 24 gesetzt. Siehe die Gnuplot-Dokumentation für eine Beschreibung weiterer Parameter, die für ein Postscript-Terminal gesetzt werden können.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

12.6 Gnuplot_pipes Formatfunktionen

Funktion: gnuplot_start ()

Öffnet eine Pipe, die im Grafikformat gnuplot_pipes für den Austausch der Daten genutzt wird.

Funktion: gnuplot_close ()

Schließt die Pipe, die im Grafikformat gnuplot_pipes für den Austausch der Daten genutzt wird.

Funktion: gnuplot_restart ()

Schließt die Pipe, die im Grafikformat gnuplot_pipes für den Austausch der Daten genutzt wird, und öffnet eine neue Pipe.

Funktion: gnuplot_replot ()
Funktion: gnuplot_replot (string)

Aktualisiert die Ausgabe von Gnuplot. Wird gnuplot_replot mit einer Zeichenkette string aufgerufen, die Gnuplot-Kommandos enthält, dann werden die Kommandos vor der Aktualisierung an Gnuplot gesendet.

Funktion: gnuplot_reset ()

Im Grafikformat gnuplot_pipes wird Gnuplot zurückgesetzt. Um die Anzeige zu aktualisieren, kann das Kommando gnuplot_replot nach dem Kommando gnuplot_reset ausgeführt werden.


[ << ] [ >> ]           [Top] [Contents] [Index] [ ? ]

This document was generated by Robert on Juli, 9 2012 using texi2html 1.76.